মাস্টার এক্সেল:সাধারণ সূত্র সহ কোষে অক্ষর গণনা করুন

এক্সেল কক্ষে অক্ষর গণনা করা আপনার ধারণার চেয়ে অনেক সহজ। কয়েকটি সহজ সূত্রের সাহায্যে, আপনি একটি একক কক্ষ বা একাধিক কক্ষে অক্ষরের সংখ্যা গণনা করতে পারেন পাশাপাশি মোট নির্দিষ্ট অক্ষর পেতে পারেন।

আপনি যদি আপনার ডেটা রপ্তানি করার প্রস্তুতি নিচ্ছেন এবং প্রতি কক্ষে অক্ষর সীমিত করতে চান বা একটি নির্দিষ্ট অক্ষরের সংঘটনের সংখ্যা খুঁজে পেতে চান, তাহলে Microsoft Excel এ কীভাবে তা দেখুন।

এক্সেলের একটি একক কক্ষে অক্ষর গণনা করুন

একটি কক্ষে মোট অক্ষর সংখ্যা পেতে, আপনি এক্সেল LEN ফাংশন ব্যবহার করবেন। সূত্রের সিনট্যাক্স হল LEN(সেল), যেখানে আপনি আর্গুমেন্টের জন্য একটি সেল রেফারেন্স লিখবেন।

উদাহরণ হিসেবে, আপনি এই সূত্রটি ব্যবহার করে A2 কক্ষে অক্ষর গণনা করতে পারেন:

=LEN(A2)

মনে রাখবেন যে বিরাম চিহ্ন এবং স্পেস উভয়ই অক্ষর হিসাবে গণনা করে, যেমন স্ট্রিংয়ের শেষ অক্ষরের পরে যে কোনও স্পেস থাকে।

টিপ:আপনি LENB ফাংশন ব্যবহার করে একটি ঘরে বাইটের সংখ্যাও গণনা করতে পারেন। উদাহরণস্বরূপ, উপরের উদাহরণের জন্য =LENB(A2) ব্যবহার করুন।

হতে পারে আপনি একাধিক কক্ষে অক্ষরের সংখ্যা চান। আপনি LEN ফাংশন ব্যবহার করতে পারেন এবং সূত্রে SUM ফাংশন যোগ করতে পারেন।

উদাহরণস্বরূপ, নিম্নলিখিত সূত্রের সাহায্যে আপনি A2, A4 এবং A6 কক্ষে অক্ষরের সংখ্যা গণনা করতে পারেন:

=SUM(LEN(A2),LEN(A4),LEN(A6))

কোষ পরিসরে অক্ষর গণনা করুন

আপনি যদি একাধিক সংলগ্ন কক্ষে মোট অক্ষর সংখ্যা পেতে চান, আপনি উপরের সূত্রটি ব্যবহার করে প্রতিটি কক্ষের রেফারেন্স সহজেই তালিকাভুক্ত করতে পারেন, তবে আরও ভাল উপায় আছে। আপনি এখনও LEN এবং SUM ফাংশন ব্যবহার করবেন ঘরের একটি পরিসরে অক্ষর গণনা করতে।

উদাহরণস্বরূপ, আপনি এই সূত্রের সাহায্যে A2 থেকে A4 কক্ষে অক্ষরের সংখ্যা পেতে পারেন:

=SUM(LEN(A2:A4))

আপনি দেখতে পাচ্ছেন, আপনি আপনার মোট পেতে সূত্রের LEN অংশের মধ্যে সেল পরিসর যোগ করুন।

টিপ:আপনি যদি SUMPRODUCT ফাংশনের সাথে পরিচিত হন তবে আপনি এটিকে এই ক্ষেত্রে SUM ফাংশনের মতোই ব্যবহার করতে পারেন৷ আমাদের উদাহরণের জন্য, আপনি একই ফলাফলের জন্য =SUMPRODUCT(LEN(A2:A4)) লিখতে পারেন৷

মাল্টিপল সেল রেঞ্জ

দুটি ভিন্ন সেল রেঞ্জে অক্ষর গণনা করতে, আপনি SUM এবং LEN ফাংশন ব্যবহার করা চালিয়ে যেতে পারেন।

এখানে, আমরা এই সূত্রের সাহায্যে A2 থেকে A4 প্লাস C2 থেকে C4 কক্ষের গণনা পাব:

=SUM(LEN(A2:A4),LEN(C2:C4))

এই ক্ষেত্রে, আপনি SUM ফাংশনের সূত্রের জন্য বন্ধনীর মধ্যে উভয় LEN সূত্র যোগ করুন।

এক্সেলের একটি কক্ষে নির্দিষ্ট অক্ষর গণনা করুন

হতে পারে এটি একটি নির্দিষ্ট চরিত্রের গণনা যা আপনাকে খুঁজে বের করতে হবে। এর জন্য, আপনি SUBSTITUTE ফাংশনের সাথে LEN ব্যবহার করবেন।

এই উদাহরণে, আমরা সেল A1-এ L-এর সংখ্যা গণনা করতে চাই। আপনি এই সূত্রটি ব্যবহার করবেন:

=LEN(A2)-LEN(SUBSTITUTE(A2,"L",""))

আপনি দেখতে পাচ্ছেন আমাদের 1 এর ফলাফল সঠিক। এখানে সূত্র কাঠামোর ভেতর থেকে একটি ভাঙ্গন রয়েছে:

• SUBSTITUTE(A2,"L","") L অক্ষরের সমস্ত উদাহরণকে A2 কক্ষে একটি খালি স্ট্রিং দিয়ে প্রতিস্থাপন করে৷
• LEN(SUBSTITUTE(A2,"L","")) A2 কক্ষে অক্ষর গণনা করে (L অক্ষর ছাড়া)।
• LEN(A2) কক্ষ A2-এ মোট অক্ষর গণনা করে।
• LEN(A2)-LEN(SUBSTITUTE(A2,"L","")) A2 কক্ষের মোট অক্ষর সংখ্যা থেকে অক্ষর গণনা (L অক্ষর ছাড়া) বিয়োগ করে।

লেটার কেস উপেক্ষা করে নির্দিষ্ট অক্ষর

আপনি যেমন লক্ষ্য করবেন, উপরের সূত্রটি আমাদের ফলাফল হিসাবে L অক্ষরের একটি উদাহরণ দেয়। এটি কারণ সূত্রে বড় হাতের অক্ষর L রয়েছে, তাই এটি ছোট হাতের অক্ষরগুলির সন্ধান করে না।

এই কেস-সংবেদনশীলতার জন্য অ্যাকাউন্ট করতে, আপনি SUBSTITUTE সূত্রে UPPER বা LOWER যোগ করতে পারেন। সংক্ষেপে, এটি খালি টেক্সট স্ট্রিং দিয়ে, ক্ষেত্রে নির্বিশেষে সমস্ত ঘটনাকে প্রতিস্থাপন করে৷

একই উদাহরণ ব্যবহার করে, আমরা নিম্নরূপ সূত্রে UPPER যোগ করব:

=LEN(A2)-LEN(SUBSTITUTE(UPPER(A2),"L",""))

এইবার, আমরা 3 এর ফলাফল পেয়েছি যার মধ্যে বড় এবং ছোট হাতের L’s উভয়ই রয়েছে।

কোষ পরিসরে নির্দিষ্ট অক্ষর গণনা করুন

আপনি এতদূর যা শিখেছেন তা নিতে চান এবং আরও এগিয়ে যেতে চান? এই শেষ বিভাগে আমরা আপনাকে দেখাব কিভাবে একটি নির্দিষ্ট অক্ষরকে বিভিন্ন কক্ষে গণনা করতে হয়। আপনি মূলত LEN, SUBSTITUTE এবং SUM একত্রিত করবেন।

এই সূত্রের সাহায্যে, আপনি A2 থেকে A4 সেল রেঞ্জে L-এর সংখ্যা গণনা করতে পারেন:

=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(UPPER(A2:A4),"L","")))

এখানে, আমরা অক্ষরের ক্ষেত্রে নির্বিশেষে L অক্ষরের সমস্ত দৃষ্টান্ত খুঁজে পেতে SUBSTITUTE সূত্রে UPPER রাখি।

একবার আপনি আপনার ওয়ার্কশীটে এই ফাংশন এবং সূত্রগুলি ব্যবহার করা শুরু করলে, প্রতিবার এক্সেলে অক্ষর গণনা করা সহজ হয়ে যায়। অক্ষর গণনার জন্য আপনার প্রয়োজন যাই হোক না কেন, ম্যানুয়ালি অক্ষর গণনার পরিবর্তে Excel কে কাজ করতে দিন।

আরও জানতে, Microsoft Excel এ COUNTIFS, SUMIFS, এবং AVERAGEIFS ব্যবহার করার জন্য আমাদের টিউটোরিয়াল দেখুন।