VBA ছাড়াই ইন্টারেক্টিভ এক্সেল ওয়ার্কবুক তৈরি করুন:একটি ধাপে ধাপে নির্দেশিকা

এই টিউটোরিয়ালে, আমরা আপনাকে দেখাব কিভাবে কোনো VBA ছাড়াই এই ইন্টারেক্টিভ ফাইলগুলি তৈরি করা যায়।

1. আপনার ডেটাসেট প্রস্তুত করুন

একটি ইন্টারেক্টিভ এক্সেল ফাইল তৈরি করতে, আপনাকে অবশ্যই আপনার ডেটাসেট পরিষ্কার এবং গঠন করতে হবে। কার্যকর ইন্টারেক্টিভ আচরণ তৈরি করার জন্য একটি ভাল-ফরম্যাট করা এবং কাঠামোগত ডেটাসেট অত্যন্ত গুরুত্বপূর্ণ।

• আপনার ডেটাসেট পরিষ্কার করুন।
• ডুপ্লিকেট এবং স্পেস সরান।
• সঠিক বিন্যাস এবং ডেটা টাইপের সমস্যা।

ডেটাকে টেবিলে রূপান্তর করুন

• ডেটাসেট নির্বাচন করুন।
• ঢোকান -এ যান ট্যাব>> টেবিল নির্বাচন করুন .
• চেক করুন আমার টেবিলে হেডার আছে .
• ঠিক আছে ক্লিক করুন .

• টেবিলের নাম পরিবর্তন করুন:
  • টেবিল ডিজাইন এ যান ট্যাব>> টেবিলের নাম নির্বাচন করুন এবং এটিকে একটি প্রাসঙ্গিক নাম দিন, যেমন বিক্রয় .

2. ডেটা যাচাইকরণ ড্রপ-ডাউন তালিকা ব্যবহার করুন

ড্রপ-ডাউন তালিকাগুলি ইন্টারেক্টিভ এক্সেল ফাইল তৈরির জন্য অপরিহার্য উপাদান। একটি ড্রপ-ডাউন তালিকা দ্রুত, সামঞ্জস্যপূর্ণ, এবং নিয়ন্ত্রিত ব্যবহারকারী ইনপুট সক্ষম করে। পরে, আপনি এটিকে ডেটা, চার্ট এবং কেপিআইগুলি ইন্টারেক্টিভভাবে ফিল্টার করতে ব্যবহার করতে পারেন।

পদক্ষেপ:

সহায়তা তালিকা তৈরি করুন: আপনার পত্রকের উপরে বা ডানদিকে সহায়ক তালিকা তৈরি করুন। আপনি এইগুলি পরে লুকাতে পারেন৷

• একটি ঘর নির্বাচন করুন এবং অনন্য অঞ্চলগুলি তালিকাভুক্ত করতে নিম্নলিখিত সূত্রটি লিখুন:

=SORT(UNIQUE(Sales[Region]))

• একটি ঘর নির্বাচন করুন এবং পণ্যের নাম তালিকাভুক্ত করতে নিম্নলিখিত সূত্রটি লিখুন:

=SORT(UNIQUE(Sales[Product]))

• ঐচ্ছিক: অনন্য তালিকা ছড়িয়ে দেওয়ার জন্য সূত্র সন্নিবেশ করার আগে প্রতিটি তালিকার উপরে "সমস্ত" যোগ করুন।

ড্রপ-ডাউন তালিকা তৈরি করুন:

• যে ঘরটি আপনি ড্রপ-ডাউন করতে চান সেটি নির্বাচন করুন (যেমন, B2)।
• ডেটা-এ যান ট্যাব>> ডেটা যাচাইকরণ নির্বাচন করুন .
• অনুমতি এর অধীনে , তালিকা বেছে নিন .
• সূত্রে , হেল্পার কলাম থেকে অঞ্চল তালিকা নির্বাচন করুন।

• ঠিক আছে ক্লিক করুন .

• অনুরূপ পদক্ষেপ অনুসরণ করে, পণ্যের জন্য একটি ড্রপ-ডাউন তালিকা তৈরি করুন।
• অনুমতি এর অধীনে , তালিকা বেছে নিন .
• সূত্রে , সহায়ক কলাম থেকে পণ্য তালিকা নির্বাচন করুন।

টিপ: আপনি তালিকাগুলির জন্য একটি নামযুক্ত পরিসর তৈরি করতে পারেন এবং তারপরে ডেটা যাচাইকরণে এটি ব্যবহার করতে পারেন।

3. একটি ড্রপ-ডাউন

একটি ড্রপ-ডাউন সহ গতিশীল সূত্রগুলিকে একত্রিত করা স্বয়ংক্রিয়ভাবে KPI এবং ফিল্টার ডেটা আপডেট করে৷

KPI তৈরি করুন:

• মোট রাজস্ব:

=SUMIFS(
Sales[Revenue],
Sales[Region], IF($B$2="All","*", $B$2),
Sales[Product], IF($B$4="All","*", $B$4))

• গড় ছাড়:

=AVERAGEIFS(
Sales[Discount],
Sales[Region], IF($B$2="All","*", $B$2),
Sales[Product], IF($B$4="All","*", $B$4))

পরিচ্ছন্ন চেহারার জন্য শতাংশ বিন্যাস প্রয়োগ করুন।

• মোট অর্ডার:

=COUNTIFS(
Sales[Region], IF($B$2="All","*", $B$2),
Sales[Product], IF($B$4="All","*", $B$4))

• বিক্রীত মোট ইউনিট:

=SUMIFS(
Sales[Units],
Sales[Region], IF($B$2="All","*", $B$2),
Sales[Product], IF($B$4="All","*", $B$4))

পরীক্ষা ইন্টারঅ্যাকটিভিটি:

• ড্রপ-ডাউন তালিকা থেকে একটি অঞ্চল এবং পণ্য নির্বাচন করুন।
• KPI স্বয়ংক্রিয়ভাবে আপডেট হয়।

4. নামযুক্ত রেঞ্জের সাথে ডায়নামিক চার্ট তৈরি করুন

ব্যবহারকারী নির্বাচনের উপর ভিত্তি করে স্বয়ংক্রিয়ভাবে আপডেট হওয়া চার্ট তৈরি করুন।

ফিল্টার করা ডেটা:

=FILTER(
CHOOSE({1,2}, Sales[Date], Sales[Revenue]),
IF($B$2="All", Sales[Region]<>"", Sales[Region]=$B$2) *
IF($B$4="All", Sales[Product]<>"", Sales[Product]=$B$4),
"No rows")

একটি গতিশীল নামের পরিসর সংজ্ঞায়িত করুন:

• সূত্র -এ যান ট্যাব>>নেম ম্যানেজার নির্বাচন করুন>> নতুন নির্বাচন করুন .
• নাম: ফিল্টার করা তারিখগুলি
• উল্লেখ করে:

=INDEX('Interactive Sheet'!$B$7#, ,1)

• নাম: ফিল্টার করা আয়
• উল্লেখ করে:

=INDEX('Interactive Sheet'!$B$7#, ,2)

চার্ট তৈরি করুন:

• ঢোকান -এ যান ট্যাব>> চার্ট থেকে>> লাইন চার্ট নির্বাচন করুন .
• চার্টে ডান ক্লিক করুন>> ডেটা নির্বাচন করুন বেছে নিন .

• সিরিজ মানগুলির জন্য, টাইপ করুন:

='Interactive Sheet'!FilteredRevenue

• অনুভূমিক অক্ষ লেবেলের জন্য:

='Interactive Sheet'!FilteredDates

পরীক্ষা ইন্টারঅ্যাকটিভিটি:

• পূর্ব অঞ্চল এবং সমস্ত পণ্য বেছে নিন।
• চার্টটি সমস্ত প্রাসঙ্গিক ডেটা দেখায়৷
৷

• একটি নির্দিষ্ট অঞ্চল এবং একটি নির্দিষ্ট পণ্য বেছে নিন।
• চার্টটি তাৎক্ষণিকভাবে ফিল্টার করে।
• এটি VBA ছাড়া যেকোনো সংমিশ্রণের জন্য কাজ করে।

5. ভিজ্যুয়াল ফিডব্যাকের জন্য শর্তসাপেক্ষ ফর্ম্যাটিং ব্যবহার করুন

শর্তসাপেক্ষ ফরম্যাটিং সহ তাৎক্ষণিকভাবে মূল মান বা ব্যবহারকারীর পছন্দ হাইলাইট করুন।

পদক্ষেপ:

• আপনার ডেটা পরিসীমা নির্বাচন করুন৷
৷
• হোম এ যান ট্যাব>> শর্তাধীন বিন্যাস নির্বাচন করুন>> নতুন নিয়ম নির্বাচন করুন .
• চয়ন করুন কোন কক্ষ বিন্যাস করতে হবে তা নির্ধারণ করতে একটি সূত্র ব্যবহার করুন .
• নিম্নলিখিত সূত্র সন্নিবেশ করান:

=AND(OR('Interactive Sheet'!$B$2="All", $C2='Interactive Sheet'!$B$2), OR('Interactive Sheet'!$B$4="All", $F2='Interactive Sheet'!$B$4))

• একটি হাইলাইট রঙ চয়ন করুন৷
৷
• ঠিক আছে ক্লিক করুন .

ফিল্টার নির্বাচনকে চাক্ষুষভাবে শক্তিশালী করে, শুধুমাত্র মিলে যাওয়া সারি হাইলাইট করা হয়।

6. PivotTables, Slicers, এবং Interactive Charts

PivotTables, PivotCharts, এবং Slicers হল Excel এর মূল ইন্টারেক্টিভ বৈশিষ্ট্য যা ডেটা ফিল্টারিংকে অবিশ্বাস্যভাবে সহজ করে তোলে।

পিভট টেবিল তৈরি করুন:

• আপনার ডেটা পরিসীমা নির্বাচন করুন৷
৷
• সন্নিবেশ এ যান ট্যাব>> পিভটটেবল নির্বাচন করুন .
• একটি অবস্থান নির্বাচন করুন:নতুন অথবা বিদ্যমান ওয়ার্কশীট .
• ঠিক আছে ক্লিক করুন .

• পিভটটেবল ক্ষেত্র থেকে :
  • টেনে আনুন পণ্য সারিতে এলাকা।
  • টেনে আনুন রাজস্ব মান -এ এলাকা।

পিভটচার্ট তৈরি করুন:

• পিভট টেবিল নির্বাচন করুন।
• পিভটটেবিল বিশ্লেষণ-এ যান ট্যাব>> পিভটচার্ট নির্বাচন করুন .
• একটি ক্লাস্টারড কলাম নির্বাচন করুন চার্ট।
• ঠিক আছে ক্লিক করুন .

ইন্টারেক্টিভ স্লাইসার যোগ করুন:

• পিভটটেবিল বিশ্লেষণ-এ যান ট্যাব>> স্লাইসার ঢোকান নির্বাচন করুন .
• ফিল্টার করার জন্য একটি ক্ষেত্র বেছে নিন, যেমন:
  • অঞ্চল, পণ্য, বিক্রয়কর্মী, ইত্যাদি।
• আপনি তাৎক্ষণিকভাবে চার্ট এবং টেবিল ফিল্টার করতে স্লাইসারের বোতামে ক্লিক করতে পারেন।

• স্লাইসার এবং চার্ট একসাথে রাখতে, আপনি তাদের গোষ্ঠীবদ্ধ করতে পারেন।
• চার্টের কাছাকাছি বা স্লাইসারগুলি রাখুন, সমস্ত বস্তু নির্বাচন করুন (চার্ট এবং স্লাইসারগুলি), তারপর ডান-ক্লিক করুন এবং গ্রুপ নির্বাচন করুন .

শেয়ারড স্লাইসারের সাথে একাধিক পিভটটেবল সংযুক্ত করা হচ্ছে

• একই ডেটা উৎস থেকে একাধিক পিভট টেবিল তৈরি করুন।
• স্লাইসার ঢোকান .
• স্লাইসারে ডান-ক্লিক করুন>> সংযোগ প্রতিবেদন করুন নির্বাচন করুন .
• একাধিক PivotTables-এ স্লাইসার সংযুক্ত করুন।

• এখন, আপনার ড্যাশবোর্ড শিটে স্লাইসার এবং চার্ট কপি করুন।
• আপনি PivotTable শীট লুকিয়ে রাখতে পারেন।

7. নেভিগেশনের জন্য হাইপারলিঙ্ক ব্যবহার করুন

আপনার এক্সেল ফাইলটিকে একটি ক্লিকযোগ্য অ্যাপের মতো অনুভব করতে, আপনি নেভিগেশনের জন্য হাইপারলিঙ্ক ব্যবহার করতে পারেন। এটি ব্যবহারকারীদের বিভিন্ন শীট, চার্ট বা টেবিলে যেতে দেয়৷

পদক্ষেপ:

• সন্নিবেশ এ যান ট্যাব>> ইলাস্ট্রেশন থেকে>> আকৃতি নির্বাচন করুন>> আয়তক্ষেত্র নির্বাচন করুন .
• আকৃতিটির নাম "বিক্রয় ডেটা"।
• আকৃতিতে ডান-ক্লিক করুন>> লিঙ্ক নির্বাচন করুন .

• হাইপারলিঙ্ক ঢোকান-এ ডায়ালগ বক্স:
• এই নথিতে স্থান নির্বাচন করুন>> সেল রেফারেন্স A1 টাইপ করুন>> বিক্রয় নির্বাচন করুন৷ শীট।
• ঠিক আছে ক্লিক করুন .

• এই নথিতে স্থান নির্বাচন করুন>> সেল রেফারেন্স A3 টাইপ করুন>> পিভট টেবিল নির্বাচন করুন শীট।
• ঠিক আছে ক্লিক করুন .

• একটি পরিষ্কার চেহারার জন্য এটিকে একটি বোতামের মতো ফর্ম্যাট করুন৷
• এই ধরনের নেভিগেশন হাইপারলিঙ্ক ব্যবহারকারীদের সহজেই একটি "ড্যাশবোর্ড" এবং বিভিন্ন "বিশদ" শীটের মধ্যে যেতে দেয়।

ফাইনাল ইন্টারেক্টিভ এক্সেল ফাইল:

• নীচের উদাহরণটি সমস্ত অঞ্চল এবং নির্বাচিত পণ্য "আনুষঙ্গিক" দেখায়৷
৷
• স্লাইসার থেকেও নির্বাচন করা যেতে পারে।
• সমস্ত ডেটা স্বয়ংক্রিয়ভাবে আপডেট হয়।

টিপস

• আমরা বিভিন্ন ইন্টারেক্টিভ পদ্ধতি দেখানোর জন্য একটি গতিশীল চার্ট (ফিল্টার ফাংশন ব্যবহার করে) এবং একটি পিভটচার্ট উভয়ই প্রদর্শন করেছি। আপনি আপনার প্রয়োজনে সবচেয়ে উপযুক্ত যে কোন প্রকার বেছে নিতে পারেন।
• আপনি ফর্ম কন্ট্রোলগুলিও অন্বেষণ করতে পারেন, যা VBA এর প্রয়োজন ছাড়াই আরও ইন্টারেক্টিভ বিকল্পগুলি অফার করে৷
• একটি অনুসন্ধান বাক্স তৈরি করতে, আপনি ডায়নামিক XLOOKUP ফাংশন ব্যবহার করতে পারেন৷

অভ্যাস ওয়ার্কবুক ডাউনলোড করুন

উপসংহার

এই বৈশিষ্ট্যগুলি এবং কৌশলগুলি ব্যবহার করে, আপনি কোনও VBA ছাড়াই পরিশীলিত, ইন্টারেক্টিভ এক্সেল ফাইল তৈরি করতে পারেন। সর্বাধিক ইন্টারঅ্যাক্টিভিটির জন্য একাধিক কৌশল একত্রিত করা মূল বিষয়। সর্বদা আপনার ইন্টারেক্টিভ উপাদানগুলি পুঙ্খানুপুঙ্খভাবে পরীক্ষা করতে এবং ব্যবহারকারীদের জন্য স্পষ্ট নির্দেশাবলী প্রদান করতে ভুলবেন না। অনুশীলনের মাধ্যমে, আপনি চিত্তাকর্ষক ড্যাশবোর্ড এবং সরঞ্জামগুলি তৈরি করতে সক্ষম হবেন যা ডেটা বিশ্লেষণকে শক্তিশালী এবং ব্যবহারকারী-বান্ধব করে তোলে, সব কিছুই VBA কোডের একটি লাইন না লিখে৷