Applescript হলো অ্যাপলের কিছুটা অস্পষ্ট স্ক্রিপ্টিং ল্যাঙ্গুয়েজ, কিন্তু এটি নবীন প্রোগ্রামারদের সুবিধা নেওয়ার জন্য একটি পাওয়ারফুল টুল। কিছু চতুর Applescript যেগুলো বিরক্তিকর টাস্ক হ্যান্ডেল করে, আমরা উৎপাদনশীলতা বাড়াতে পারি এবং অটোমেশন দিয়ে ফ্রাস্ট্রেশন দূর করতে পারি।
Applescript কী?
Applescript অধিকাংশ Mac অ্যাপ্লিকেশনের সাথে ইন্টারফেস করে যেমন Finder, iTunes, QuickTime এবং Mail। আপনি যদি Automator-এ পরিচিত হন, Applescript সেটির এক種 পাওয়ার ইউজার ভার্সন।
১. হিডেন ফাইল টগল করুন
এটি অ্যাপ্লিকেশন হিসেবে সেভ করুন, এবং আপনার কাছে একটি ক্লিকযোগ্য টগল থাকবে Finder-এ হিডেন ফাইল রিভিল করার জন্য।
set newHiddenState to "YES"
try
set oldHiddenState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
if oldHiddenState is in {"1", "YES"} then
set newHiddenState to "NO"
end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenState
do shell script "killAll Finder"
২. ব্যাচ রিনেম ফাইল
এই স্ক্রিপ্ট ইউজারকে ফাইলনেমের জন্য প্রম্পট করবে এবং সিলেক্টেড ফাইলগুলোকে ঐ টেক্সট স্ট্রিং প্লাস একটি ইনক্রিমেন্টিং ইন্ডেক্স দিয়ে অটোমেটিক্যালি রিনেম করবে। এটি هيل্পফুলি এক থেকে দশ নম্বর ফাইলের জন্য লিডিং জিরোও অ্যাড করে।
-- This code comes from https://gist.github.com/oliveratgithub/
-- Open in AppleScript Editor and save as Application
-- ------------------------------------------------------------
--this is required to break the filename into pieces (separate name and extension)
set text item delimiters to "."
tell application "Finder"
set all_files to every item of (choose file with prompt "Choose the Files you'd like to rename:" with multiple selections allowed) as list
display dialog "New file name:" default answer ""
set new_name to text returned of result
--now we start looping through all selected files. 'index' is our counter that we initially set to 1 and then count up with every file.
--the 'index' number is of course required for the sequential renaming of our files!
repeat with index from 1 to the count of all_files
--using our index, we select the appropriate file from our list
set this_file to item index of all_files
set file_name_count to text items of (get name of this_file)
--if the index number is lower than 10, we will add a preceding "0" for a proper filename sorting later
if index is less than 10 then
set index_prefix to "0"
else
set index_prefix to ""
end if
--
--lets check if the current file from our list (based on index-number) has even any file-extension
if number of file_name_count is 1 then
--file_name-count = 1 means, we extracted only 1 text-string from the full file name. So there is no file-extension present.
set file_extension to ""
else
--yup, we are currently processing a file that has a file-extension
--we have to re-add the original file-extension after changing the name of the file!
set file_extension to "." & item -1 of file_name_count
end if
--let's rename our file, add the sequential number from 'index' and add the file-extension to it
set the name of this_file to new_name & index_prefix & index & file_extension as string
end repeat
--congratulations for successfully accomplishing the batch renaming task :)
display alert "All done! Renamed " & index & " files with '" & new_name & "' for you. Have a great day! :)"
end tell
৩. ইমেজ পারসেন্টেজ অনুযায়ী স্কেল করুন
এই স্ক্রিপ্ট ইমেজগুলকে তাদের আসল সাইজের ৫০% স্কেল করবে।
-- Prompt for an image
set theImageFile to choose file of type "public.image" with prompt "Please select an image:"
-- Locate an output folder
set theOutputFolder to (path to desktop folder as string)
-- Launch Image Events
tell application "Image Events"
launch
-- Open the image
set theImage to open theImageFile
tell theImage
-- Determine a save name for the image
set theName to name
set theSaveName to "smlr-" & theName
-- Scale the image by 50%
scale by factor 0.5
-- Save the image to the output folder, using the save name
save as file type in (theOutputFolder & theSaveName)
-- Close the image
close
end tell
end tell
৪. ইমেজ পিক্সেল উইডথ অনুযায়ী স্কেল করুন
এটি আগের স্ক্রিপ্টের মতো শুরু হয় কিন্তু পিক্সেল উইডথ অনুযায়ী স্কেল করে। এটি ইউজারকে ডিজায়ারড পিক্সেল উইডথের জন্য প্রম্পট করবে এবং নতুন ফাইলের নামের শুরুতে সেই পিক্সেল উইডথ অ্যাপেন্ড করবে।
-- Prompt for an image
set theImageFile to choose file of type "public.image" with prompt "Please select an image:"
set dialogResult to (display dialog "Enter desired pixel width:" default answer "")
try
set pixelWidth to (text returned of dialogResult) as integer
end try
-- Locate an output folder
set theOutputFolder to (path to desktop folder as string)
-- Launch Image Events
tell application "Image Events"
launch
-- Open the image
set theImage to open theImageFile
tell theImage
-- Determine a save name for the image
set theName to name
set theSaveName to (pixelWidth as text) & "-px-" & theName
-- Scale the image to pixelWidth
scale to size pixelWidth
-- Save the image to the output folder, using the save name
save as file type in (theOutputFolder & theSaveName)
-- Close the image
close
end tell
end tell
৫. ফোল্ডার বাকআপ বাঞ্ছিত ডেস্টিনেশনে
এই সিম্পল স্ক্রিপ্ট একটি বাঞ্ছিত ফোল্ডারকে একটি বাঞ্ছিত ডেস্টিনেশনে ডুপ্লিকেট করে যা জটিল ড্র্যাগ-অ্যান্ড-ড্রপ কপি করা কিছুটা কম পেইনফুল করে।
set backupTarget to (choose folder with prompt "Select a Backup Target")
set backupDestination to (choose folder with prompt "Select a Backup Destination")
tell application "Finder"
duplicate folder backupTarget to folder backupDestination
end tell
উপসংহার
AppleScript-র সম্পর্কে আরও জানতে, আপনি Apple-এর নিজস্ব ডকুমেন্টেশন চেক আউট করতে পারেন। আরও ভালো হলো MacOSXAutomation.com, যা নবীন-বান্ধব।
